1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94

// ===================== Checkers (from Checking Out-of-Order Traffic) =====================
class id_scoreboard #(type T = logic [31:0]);
  string name;
  protected T exp_q[int][$];
  int n_added, n_matched, n_errors;
  function new(string name); this.name = name; endfunction
  virtual function void add_expected(int id, T item);
    exp_q[id].push_back(item);
    n_added++;
  endfunction
  virtual function void check_actual(int id, T item);
    T exp;
    if (!exp_q.exists(id) || exp_q[id].size() == 0) begin
      n_errors++;
      $display("%s: UNEXPECTED response for ID %0d with nothing outstanding (got %h)", name, id, item);
      return;
    end
    exp = exp_q[id].pop_front();
    if (exp_q[id].size() == 0) exp_q.delete(id);
    if (item !== exp) begin
      n_errors++;
      $display("%s: MISMATCH ID %0d expected %h got %h", name, id, exp, item);
    end else n_matched++;
  endfunction
  function int outstanding();
    int n = 0;
    foreach (exp_q[id]) n += exp_q[id].size();
    return n;
  endfunction
  function int outstanding_on(int id);
    return exp_q.exists(id) ? exp_q[id].size() : 0;
  endfunction
  virtual function void flush();               // reset: outstanding work is dropped by spec
    exp_q.delete();
  endfunction
endclass

class drain_scoreboard #(type T = logic [31:0]) extends id_scoreboard #(T);
  protected longint issued_at[int][$];
  longint last_progress;
  int     max_lat, late;
  int     leaked[$], stuck[$];
  function new(string name, int max_lat);
    super.new(name);
    this.max_lat = max_lat;
  endfunction
  function void add_at(longint now, int id, T item);
    add_expected(id, item);
    issued_at[id].push_back(now);
  endfunction
  function void check_at(longint now, int id, T item);
    check_actual(id, item);
    if (issued_at.exists(id)) begin
      void'(issued_at[id].pop_front());
      if (issued_at[id].size() == 0) issued_at.delete(id);
    end
    last_progress = now;
  endfunction
  // Returns how many items passed max_lat on this cycle (each counted once).
  function int watchdog(longint now);
    int n = 0;
    foreach (issued_at[id])
      if (now - issued_at[id][0] == max_lat) begin
        n++;
        $display("%s: ID %0d waited %0d cycles (issued at %0d)", name, id, max_lat, issued_at[id][0]);
      end
    return n;
  endfunction
  virtual function void flush();
    super.flush();
    issued_at.delete();
  endfunction
  function void classify(longint now);
    foreach (issued_at[id])
      foreach (issued_at[id][k])
        if (last_progress - issued_at[id][k] > max_lat) leaked.push_back(id);
        else stuck.push_back(id);
    foreach (leaked[i]) $display("%s: LEAK ID %0d never answered", name, leaked[i]);
    if (stuck.size() != 0) $display("%s: STUCK IDs %p, no response for %0d cycles", name, stuck, now - last_progress);
  endfunction
endclass

class mem_model;
  protected bit [7:0] bytes[bit [31:0]];
  function void write(bit [31:0] addr, bit [31:0] data, bit [3:0] strb);
    for (int b = 0; b < 4; b++) if (strb[b]) bytes[addr + b] = data[8*b +: 8];
  endfunction
  function bit [31:0] read(bit [31:0] addr);
    bit [31:0] w;
    for (int b = 0; b < 4; b++) w[8*b +: 8] = bytes.exists(addr + b) ? bytes[addr + b] : 8'h00;
    return w;
  endfunction
endclass