1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87

// dcr_cov.svh: DCRouter step 8, a functional coverage model. Included inside `module tb` after
// dcr_env.svh and dcr_sva.svh (it uses ctrl_q). Each bin is a named counter: bins are declared
// up front, so a bin never hit is reported as a hole. (A covergroup expresses the same model;
// named counters keep it runnable on every simulator the course uses.)
int cov [string];
function automatic void bin(string name);  if (!cov.exists(name)) cov[name] = 0;  endfunction
function automatic void hit(string name);  if (cov.exists(name)) cov[name]++; else $display("ERROR: undeclared bin %s", name);  endfunction
function automatic string len_class(int len);
  return len == 0 ? "len0" : len == 1 ? "len1" : len == 15 ? "len15" : "len2-14";
endfunction

initial begin
  string lc [4] = '{"len0", "len1", "len2-14", "len15"};
  for (int d = 0; d < 4; d++) for (int p = 0; p < 2; p++) foreach (lc[k]) bin($sformatf("hdr dst%0d prio%0d %s", d, p, lc[k]));
  foreach (lc[k]) if (k != 0) for (int p = 0; p < 2; p++) bin($sformatf("fault bad CRC prio%0d %s", p, lc[k]));
  for (int p = 0; p < 2; p++) bin($sformatf("fault len0 prio%0d", p));
  for (int i = 0; i < 4; i++) begin
    bin($sformatf("input%0d FIFO full", i));     bin($sformatf("output%0d out of credits", i));
    bin($sformatf("wake by input%0d alone", i)); bin($sformatf("CTRL port%0d disabled", i));
    bin($sformatf("ERR_CNT%0d cleared", i));     bin($sformatf("PKT_CNT%0d cleared", i));
    bin($sformatf("ERR_CNT%0d saturated", i));
  end
  bin("two or more tails in one cycle");  bin("back-to-back packets to different outputs");
  bin("sleep entered");  bin("credit returned while asleep");
  bin("CTRL prio_en 0");  bin("CTRL prio_en 1");  bin("CTRL lp_en 0");
  bin("CTRL read before any write");  bin("STATUS read");  bin("unmapped address accessed");
end

bit cv_hdr_next [4] = '{1, 1, 1, 1}, cv_last_tail [4] = '{0, 0, 0, 0}, cv_ctrl_written = 0, cv_slept = 0;
int cv_last_dst [4] = '{-1, -1, -1, -1}, cv_out_prio [4], cv_out_len [4];
bit cv_started [4] = '{0, 0, 0, 0};
always @(posedge clk) if (!rst) begin
  for (int i = 0; i < 4; i++) begin
    if (in_vld[i] && in_rdy[i]) begin
      logic [15:0] d;
      d = in_data[16*i +: 16];
      if (cv_hdr_next[i]) begin
        hit($sformatf("hdr dst%0d prio%0d %s", d[15:14], d[13], len_class(d[12:9])));
        if (cv_last_tail[i] && cv_last_dst[i] != d[15:14]) hit("back-to-back packets to different outputs");
        cv_last_dst[i] = d[15:14];
      end
      cv_last_tail[i] = in_last[i];
      cv_hdr_next[i] = in_last[i];
    end else if (!in_vld[i]) cv_last_tail[i] = 0;
    if (in_vld[i] && !in_rdy[i] && !sleeping && ctrl_q[i]) hit($sformatf("input%0d FIFO full", i));
    if (occ[i] == 4) hit($sformatf("output%0d out of credits", i));
    if (sleeping && in_vld == 4'(1 << i)) hit($sformatf("wake by input%0d alone", i));
  end
  for (int o = 0; o < 4; o++) if (out_vld[o]) begin
    logic [15:0] d;
    d = out_data[16*o +: 16];
    if (!cv_started[o]) begin cv_started[o] = 1; cv_out_prio[o] = d[13]; cv_out_len[o] = d[12:9]; end
    if (out_last[o]) begin
      cv_started[o] = 0;
      if (out_err[o]) hit(cv_out_len[o] == 0 ? $sformatf("fault len0 prio%0d", cv_out_prio[o])
                                            : $sformatf("fault bad CRC prio%0d %s", cv_out_prio[o], len_class(cv_out_len[o])));
    end
  end
  if ($countones(out_last) >= 2) hit("two or more tails in one cycle");
  if (sleeping && !cv_slept) hit("sleep entered");
  cv_slept = sleeping;
  if (sleeping && out_crd != 0) hit("credit returned while asleep");
  if (psel && penable) begin                        // register operations, from the APB pins
    if (!pwrite && paddr == 8'h00 && !cv_ctrl_written) hit("CTRL read before any write");
    if (!pwrite && paddr == 8'h04) hit("STATUS read");
    if (pslverr) hit("unmapped address accessed");
    if (pwrite && paddr == 8'h00) begin
      cv_ctrl_written = 1;
      hit($sformatf("CTRL prio_en %0d", pwdata[4]));
      if (!pwdata[5]) hit("CTRL lp_en 0");
      for (int k = 0; k < 4; k++) if (!pwdata[k]) hit($sformatf("CTRL port%0d disabled", k));
    end
    for (int k = 0; k < 4; k++) begin
      if (pwrite && paddr == 8'h10 + 8'(4 * k)) hit($sformatf("ERR_CNT%0d cleared", k));
      if (pwrite && paddr == 8'h20 + 8'(4 * k)) hit($sformatf("PKT_CNT%0d cleared", k));
      if (!pwrite && paddr == 8'h10 + 8'(4 * k) && prdata[7:0] == 8'hFF) hit($sformatf("ERR_CNT%0d saturated", k));
    end
  end
end

function automatic void coverage_report();
  int total, got;
  total = 0; got = 0;
  foreach (cov[name]) begin total++; if (cov[name] > 0) got++; end
  $display("coverage: %0d of %0d bins hit", got, total);
  foreach (cov[name]) if (cov[name] == 0) $display("  hole: %s", name);
endfunction

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

// uses: dcrouter
// DCRouter step 8: lesson 5.10's checked hunt with the coverage model of dcr_cov.svh, then a
// phase written from the coverage holes: read CTRL before anything writes it, clear and re-read
// every counter, saturate an error counter, access an unmapped address, read STATUS, and
// disable each port while offering it a packet. Compile with +define+NO_CLOSE to run without
// that phase and see the holes it was written to fill.
module tb;
  `include "dcr_env.svh"
  `include "dcr_hunt.svh"
  `include "dcr_sva.svh"
  `include "dcr_fair.svh"
  `include "dcr_cov.svh"
  task automatic hot_spot(bit prio_on);
    apb_wr(8'h00, {26'b0, 1'b1, prio_on, 4'hF});
    gap_pct = '{0, 0, 0, 0};
    drain_pct = '{100, 100, 100, 100};
    for (int n = 0; n < 12; n++)
      for (int i = 0; i < 4; i++) queue_pkt(i, 1, i >= 2, 2);
    wait_drain(20000);
  endtask
  task automatic close_holes();
    int a0;
    apb_rd(8'h04);                                   // STATUS
    apb_rd(8'h40);                                   // unmapped (R12)
    if (rd_err !== 1'b1) fail("R12: no pslverr for unmapped address 0x40");
    for (int i = 0; i < 4; i++) queue_pkt(i, i, 0, 2, 1);   // one fault per input, so every ERR_CNT is non-zero
    wait_drain();
    for (int k = 0; k < 4; k++) begin                // clear each counter; only that one clears (R9, R10)
      apb_wr(8'h10 + 8'(4 * k), 0);  bad_pkts[k] = 0;
      apb_wr(8'h20 + 8'(4 * k), 0);  got_pkts[k] = 0;
      for (int j = 0; j < 4; j++) begin
        check_reg(8'h10 + 8'(4 * j), bad_pkts[j] > 255 ? 255 : bad_pkts[j], $sformatf("ERR_CNT%0d after clearing ERR_CNT%0d", j, k));
        check_reg(8'h20 + 8'(4 * j), got_pkts[j], $sformatf("PKT_CNT%0d after clearing PKT_CNT%0d", j, k));
      end
    end
    for (int n = 0; n < 260; n++) queue_pkt(2, 3, 0, 1, 1);   // saturate ERR_CNT2 (R9)
    wait_drain(20000);
    check_reg(8'h18, 255, "ERR_CNT2 after 260 faults");
    for (int k = 0; k < 4; k++) begin                // a disabled port accepts nothing (R1)
      apb_wr(8'h00, 32'h30 | (32'hF & ~(32'h1 << k)));
      a0 = sent_pkts[k];
      queue_pkt(k, (k + 1) % 4, 0, 2);
      repeat (30) @(posedge clk);
      if (pending() != 4) fail($sformatf("R1: disabled port %0d accepted flits", k));
      apb_wr(8'h00, 32'h3F);
      wait_drain();
    end
  endtask
  initial begin
    reset_dut();
`ifndef NO_CLOSE
    check_reg(8'h00, 32'h3F, "CTRL after reset (R11)");
`endif
    hunt();
    hot_spot(1);
    hot_spot(0);
`ifndef NO_CLOSE
    close_holes();
`endif
    final_checks();
    coverage_report();
    finish($sformatf("covered hunt: %0d packets, every check clean", sent_pkts.sum()));
  end
endmodule